/********************************************************************\

PROGRAM:        C:\\MEPS\PROG\EXAMPLE09.SAS

DESCRIPTION:  	THIS EXAMPLE USES THE 2003 FULL-YEAR FILE TO OUTPUT
               DESCRIPTIVE STATISTICS SHOWING HEALTH INSURANCE
               STATUS AND HEALTHCARE UTILIZATION.

INPUT FILE:  	C:\MEPS\DATA\H60.SAS7BDAT (2003 FULL-YEAR DATA FILE)

\********************************************************************/

FOOTNOTE 'PROGRAM: C:\MEPS\PROG\EXAMPLE09.SAS';

LIBNAME CDATA V8 'C:\MEPS\DATA' ;

TITLE1 'AHRQ MEPS DATA USERS WORKSHOP -- JULY 2006';
TITLE2 'HEALTH INSURANCE STATUS AND HEALTHCARE UTILIZATION';

PROC FORMAT;
   VALUE HLTH
   1 = '1 EXCELLENT'
   2 = '2 VERY GOOD'
   3 = '3 GOOD'
   4 = '4 FAIR'
   5 = '5 POOR';
   VALUE YESNO
   -9 = '-9 NOT ASCERTAINED'
   -8 = '-8 DK'
   -7 = '-7 REFUSED'
   -1 = '-1 INAPPLICABLE'
   1 = 'UNINSURED'
   2 = 'INSURED';
   VALUE INSCOV
   1 = 'ANY PRIVATE'
   2 = 'PUBLIC ONLY'
   3 = 'UNINSURED';
   VALUE RXTOT
   0 = '0'
   1-10 = '1-10'
   11-50 = '11-50'
   51-HIGH = 'OVER 50';
   VALUE OBTOT
   0 = '0'
   1-5 = '1-5'
   6-25 = '6-25'
   26-HIGH = 'OVER 25';
RUN;

DATA PUF79 ;
	SET CDATA.H79 (KEEP= UNINS03 INSCOV03 RXTOT03 OBTOTV03 
	                     VARPSU VARSTR PERWT03F);
	LABEL OBTOTV03= ' '
	      RXTOT03 = ' '
	      UNINS03 = ' '
	      INSCOV03= ' ';
RUN;

TITLE3 'MIN AND MAX VALUES FOR RXTOT03 AND OBTOTV03';

PROC MEANS DATA= PUF79 MIN MAX;
   VAR RXTOT03 OBTOTV03;
RUN;

TITLE3 'MEAN NUMBER OF PRESCRIPTIONS AND REFILLS BY INSURANCE COVERAGE STATUS';

PROC SURVEYMEANS DATA= PUF79 NOBS SUMWGT MEAN STDERR;
   VAR RXTOT03;
   STRATA VARSTR;
   CLUSTER VARPSU;
   WEIGHT PERWT03F;
   DOMAIN UNINS03 INSCOV03;
   FORMAT UNINS03 YESNO. INSCOV03 INSCOV. ;
RUN;

TITLE3 'MEAN NUMBER OF OFFICE VISITS BY INSURANCE COVERAGE STATUS';

PROC SURVEYMEANS DATA= PUF79 NOBS SUMWGT MEAN STDERR;
   VAR OBTOTV03;
   STRATA VARSTR;
   CLUSTER VARPSU;
   WEIGHT PERWT03F;
   DOMAIN UNINS03 INSCOV03;
   FORMAT UNINS03 YESNO. INSCOV03 INSCOV. ;
RUN;